Appendix 2 – Mplus Analysis

STEP 1:

Run growth mixture model on control cases only in Mplus and output class probabilities from the best-fitting model

DATA:

File is \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_;

VARIABLE:

NAMES are

id intervention covariate1 covariate2 covariate3 y1 y2 y3 y4 y5

trial2 trial3 trial4; !these are dummy coded trial indicator variables

USEVARIABLES are

intervention covariate1 covariate2 covariate3 y1 y2 y3 y4 y5 trial2 trial3 trial4;

USEOBSERVATIONS are intervention = 0; !control cases only

IDVARIABLE = id;

CLASSES = c (3);

ANALYSIS:

TYPE = mixture random;

MODEL:

%OVERALL%

!latent growth model

I S | y1@0 y2@6 y3@12 y4@18 y5@24;

S on I;

[I]; I;

[S]; S;

I S on covariate1 covariate2 covariate3;

C on trial2 trial3 trial4 covariate1 covariate2 covariate3;

%c#1%

[I]; !separate mean intercept for each class

[S]; !separate mean slope for each class

%c#2%

[I];

[S];

%c#3%

[I];

[S];

savedata:

file is FILENAME.dat;

save=cprobabilities; !this saves class probabilities for each control cases to external dataset

STEP 2 Mplus Code:

DATA:

File is \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_;

!this dataset includes all cases (intervention and control), with class assignment for control

cases (indicated by a 1 for the class assignment determined by pseudo-class draws using class

probabilities from Step 1, and 0 for the other two) and unknown for treatment cases (indicated

by a 1 for every class variable – see below).

VARIABLE:

NAMES are

id intervention covariate1 covariate2 covariate3 y1 y2 y3 y4 y5

psclass1 psclass2 psclass3 trial2 trial3 trial4;

USEVARIABLES are

intervention covariate1 covariate2 covariate3 y1 y2 y3 y4 y5

psclass1 psclass2 psclass3 trial2 trial3 trial4;

IDVARIABLE = id;

CLASSES = c (3);

TRAINING = psclass1 psclass2 psclass3 (MEMBERSHIP);

!these are the class assignments based on pseudo-class draws

!for intervention cases these values are psclass1=1 psclass2=1 psclass3=1

!for control cases these values are psclass=1 for the class they are assigned, and 0 for others

ANALYSIS:

TYPE = mixture random;

MODEL:

%OVERALL%

!latent growth model

I S | y1@0 y2@6 y3@12 y4@18 y5@24;

S on I;

[I]; I;

[S]; S;

I S on covariate1 covariate2 covariate3;

S on intervention; !intervention effect on latent slope

c on trial2 trial3 trial4 covariate1 covariate2 covariate3;